1 PRINT"[147]":POKE53280,5:POKE53281,0:POKE646,7
2 PRINT"*************************************"
3 PRINT"*                                   *"
4 PRINT"*          CADET'S C-64 DOS         *"
5 PRINT"*                                   *"
6 PRINT"*************************************":PRINT
10 PRINTTAB(3);"A",TAB(4)"ACCESS DIRECTORY"
20 PRINTTAB(3);"B",TAB(4)"BACKUP FILES"
30 PRINTTAB(3);"C",TAB(4)"CONSOLIDATE FILES"
40 PRINTTAB(3);"D",TAB(4)"DELETE FILES"
50 PRINTTAB(3);"E",TAB(4)"ERROR STATUS"
60 PRINTTAB(3);"F",TAB(4)"FORMAT DISK"
70 PRINTTAB(3);"G",TAB(4)"GIVE FILE A NEW NAME"
80 PRINTTAB(3);"X",TAB(4)"EXIT TO BASIC":PRINT
90 PRINT"ENTER LETTER SIGNIFYING YOUR CHOICE"
99 INPUT"WHAT IS YOUR REQUEST";X$
100 PRINT"[147]"
110 IF X$="A" THEN GOSUB 200
120 IF X$="B" THEN GOSUB 300
130 IF X$="C" THEN GOSUB 400
140 IF X$="D" THEN GOSUB 500
150 IF X$="E" THEN GOSUB 600
155 IF X$="F" THEN GOSUB 700
160 IF X$="G" THEN GOSUB 800
190 IF X$="X" THEN GOSUB 1000
199 GOTO 1
200 REM ACCESS DIRECTORY
252 OPEN 1,8,0,"$"
253 GET#1,A$,B$
254 GET#1,A$,B$
255 GET#1,A$,B$
258 C=0:IF A$<>""THEN C=ASC(A$)
260 IF B$<>""THEN C=C+ASC(B$)*256
262 PRINT MID$(STR$(C),2);TAB(3);
264 GET#1,B$:IF ST<>0 THEN 282
266 IF B$<> CHR$(34) THEN 264
268 GET #1,B$:IF B$<> CHR$(34) THEN PRINT TAB(8);B$;:GOTO 268
270 GET #1,B$:IF B$=CHR$(32) THEN 270
272 PRINT TAB(28);:C$=""
274 C$=C$+B$:GET #1,B$:IF B$<>"" THEN 274
276 PRINT LEFT$(C$,3)
280 IF ST=0 THEN254
282 PRINT " BLOCKS FREE "
284 CLOSE 1:PRINT:PRINT"HIT A KEY TO RETURN TO MENU"
290 GET X$:IFX$=""THEN 290
295 RETURN
300 REM BACKUP FILE
310 GOSUB 2000
320 OPEN 15,8,15,"C:"+NF$+"="+SF$
330 CLOSE 15:RETURN
400 REM VALIDATE DISK
410 PRINT "WARNING:OPEN FILES WILL BE DELETED."
420 PRINT"HIT Y TO VALIDATE.":INPUT"CONTINUE";Q$
430 IF Q$<>"Y" THEN RETURN
440 OPEN 1,8,15,"V0"
450 CLOSE 1:RETURN
500 REM ERASE FILE
510 INPUT "WHAT FILES TO DELETE";FI$
520 INPUT"DO YOU WISH TO CONTINUE";X$
530 IF X$<>"Y"THEN RETURN
540 OPEN 15,8,15,"S0:"+FI$
550 CLOSE 15:RETURN
600 REM DISPLAY ERROR STATUS
610 OPEN 15,8,15
620 INPUT#15,A$,B$,C$,D$
630 PRINT "ERROR STATUS:[160][160]"B$:PRINT:PRINT "ERROR NUMBER:[160][160]"A$
640 PRINT:PRINT"HIT A KEY TO RETURN TO MENU"
650 GET X$:IF X$=""THEN 650
660 CLOSE 15:RETURN
700 REM FORMAT DISK
710 PRINT "INSERT DISK TO FORMAT"
720 PRINT "ENTER DISK NAME":INPUT DISK$
730 PRINT:PRINT "ENTER EXTENDER NAME":INPUT ID$
740 PRINT"PUT DISK TO BE ERASED IN DRIVE.":PRINT"PRESS Y TO CONTINUE. ";
750 INPUT"CONTINUE";Q$:IF Q$<>"Y" THEN RETURN
760 OPEN 15,8,15,"N0:"+DISK$+","+ID$
770 CLOSE 15:RETURN
800 REM GIVE FILE NEW NAME
810 GOSUB 2000
820 OPEN 15,8,15,"R:"+NF$+"="+SF$
830 CLOSE 15:RETURN
1000 REM RETURN TO BASIC
1010 PRINT "TO ERASE WEDGE FROM MEMORY TYPE NEW."
1020 PRINT"TO RETURN TO PROGRAM TYPE RUN"
1099 END
2000 REM INPUT ROUTINE
2010 INPUT"WHAT SOURCE FILE";SF$
2020 PRINT:INPUT "WHAT IS NEW FILE NAME";NF$
2030 RETURN